Home · All Classes · Main Classes · Grouped Classes · Modules · Functions

browser.pro Example File
demos/browser/browser.pro

 TEMPLATE = app
 TARGET = browser
 QT += webkit network

 CONFIG += qt warn_on

 FORMS += \
     cookies.ui \
     cookiesexceptions.ui \
     downloaditem.ui \
     downloads.ui \
     history.ui \
     passworddialog.ui \
     settings.ui

 HEADERS += \
     autosave.h \
     browsermainwindow.h \
     browsertabproxy.h \
     chasewidget.h \
     cookiejar.h \
     downloadmanager.h \
     edittableview.h \
     edittreeview.h \
     history.h \
     modelmenu.h \
     searchlineedit.h \
     settings.h \
     sourcecodeview.h \
     squeezelabel.h \
     toolbarsearch.h \
     webview.h

 SOURCES += \
     autosave.cpp \
     browsermainwindow.cpp \
     browsertabproxy.cpp \
     chasewidget.cpp \
     cookiejar.cpp \
     downloadmanager.cpp \
     edittableview.cpp \
     edittreeview.cpp \
     history.cpp \
     modelmenu.cpp \
     searchlineedit.cpp \
     settings.cpp \
     sourcecodeview.cpp \
     squeezelabel.cpp \
     toolbarsearch.cpp \
     webview.cpp \
     main.cpp

 RESOURCES += images/images.qrc

 build_all:!build_pass {
     CONFIG -= build_all
     CONFIG += release
 }

 win32 {
    RC_FILE = browser.rc
 }

 mac {
     ICON = browser.icns
     QMAKE_INFO_PLIST = Info_mac.plist
     TARGET = Browser
 }

 # install
 target.path = $$[QT_INSTALL_DEMOS]/browser
 sources.files = $$SOURCES $$HEADERS $$RESOURCES *.pro *.html *.doc images
 sources.path = $$[QT_INSTALL_DEMOS]/browser
 INSTALLS += target sources


Copyright © 2008 Trolltech Trademarks
Qt 4.4.0-beta1